如何让控件的位置随窗体改变而改变?

发布网友 发布时间：2023-10-19 19:31

我来回答

共4个回答

热心网友 时间：2024-11-15 22:35

现在你只是想让控件一直保持在程序的最*是吧?

那就在ReSize事件裏 写上移动控件位置的代码就好了啊

举个例子

原来程序的窗体 高度300 x 宽度400
有一个按钮 大小是 高度30 x 宽度80
那要把这个按钮移动到中间 只需要
Private Sub Form_Resize()
Command1.Top = (Form1.ScaleHeight - Command1.Height) / 2
Command1.Left = (Form1.ScaleWidth - Command1.Width) / 2
End Sub

代码写成这样 是为了更好地显示原理
你可以先试下这段代码 看看是不是已经实现了你想要的功能?

代码还可以稍微简化下
Private Sub Form_Resize()
Command1.Move (Form1.ScaleWidth - Command1.Width) / 2, (Form1.ScaleHeight - Command1.Height) / 2
End Sub

还有你说的 在Frame或者其他容器中 也可以很容易的解决的
在Form_Resize()过程中 先把这个容器的大小修改到跟窗体一样的比例 就可以了

还是上面那个例子
现在添加一个Frame 然后把Command控件放进这个Frame裏
代码如下:
Private Sub Form_Resize()
Frame1.Left = 60
Frame1.Top = 30
Frame1.Width = Form1.ScaleWidth - 120
Frame1.Height = Form1.ScaleHeight - 120
Command1.Move (Frame1.Width - Command1.Width) / 2, (Frame1.Height - Command1.Height) / 2
End Sub

现在试试看是不是实现你的要求了

同样可以简化下:
Private Sub Form_Resize()
Frame1.Move 60, 30, Form1.ScaleWidth - 120, Form1.ScaleHeight - 120
Command1.Move (Frame1.Width - Command1.Width) / 2, (Frame1.Height - Command1.Height) / 2
End Sub

如果有很多个Frame的话 你自己Frame所占的窗体大小的比例 就可以了.

热心网友 时间：2024-11-15 22:35

VB自动改变控件大小

Option Explicit
Private FormOldWidth As Long
'保存窗体的原始宽度
Private FormOldHeight As Long
'保存窗体的原始高度

'在调用ResizeForm前先调用本函数
Public Sub ResizeInit(FormName As Form)
Dim Obj As Control
FormOldWidth = FormName.ScaleWidth
FormOldHeight = FormName.ScaleHeight
On Error Resume Next
For Each Obj In FormName
Obj.Tag = Obj.Left & " " & Obj.Top & " " _
& Obj.Width & " " & Obj.Height & " "
Next Obj
On Error GoTo 0
End Sub

'按比例改变表单内各元件的大小，在调用ReSizeForm前先调用ReSizeInit函数
Public Sub ResizeForm(FormName As Form)
Dim Pos(4) As Double
Dim I As Long, TempPos As Long, StartPos As Long
Dim Obj As Control
Dim ScaleX As Double, ScaleY As Double

ScaleX = FormName.ScaleWidth / FormOldWidth
'保存窗体宽度缩放比例
ScaleY = FormName.ScaleHeight / FormOldHeight
'保存窗体高度缩放比例
On Error Resume Next
For Each Obj In FormName
StartPos = 1
For I = 0 To 4
'读取控件的原始位置与大小

TempPos = InStr(StartPos, Obj.Tag, " ", vbTextCompare)
If TempPos > 0 Then
Pos(I) = Mid(Obj.Tag, StartPos, TempPos - StartPos)
StartPos = TempPos + 1
Else
Pos(I) = 0
End If
'根据控件的原始位置及窗体改变大小的比例对控件重新定位与改变大小
Obj.Move Pos(0) * ScaleX, Pos(1) * ScaleY, _
Pos(2) * ScaleX, Pos(3) * ScaleY
Next I
Next Obj
On Error GoTo 0
End Sub

Private Sub Form_Load()
Call ResizeInit(Me) '在程序装入时必须加入
End Sub

Private Sub Form_Resize()
Call ResizeForm(Me) '确保窗体改变时控件随之改变
End Sub

'大家可以放几个控件上去

参考资料：http://hi.baidu.com/%CE%DE%C1%C4%CB%A3%CB%A3%BF%E1/blog/item/9d0362240bd0cf024c088de5.html

热心网友 时间：2024-11-15 22:35

你在窗体的sizechang事件（窗体的尺寸改变时发生）中写以下代码：控件.left=窗体.left-控件.left。

热心网友 时间：2024-11-15 22:36

是窗体在屏幕的位置改变 呢？还是窗体的大小？？