用批处理搜索包含某字符串的文件夹然后删除

发布网友发布时间：2023-07-17 10:40

共2个回答

热心网友时间：2024-12-02 14:56

效果图：

批处理脚本代码：

@echo off & title 全盘扫描删除相关文件夹 By 依梦琴瑶

::设置要删除的文件夹列表文件
set List=list.txt

setlocal enabledelayedexpansion
for /f "tokens=2 delims==:" %%a in ('wmic LogicalDisk where "DriveType='3'" get DeviceID /value') do (
    pushd %%~a:\
    echo 正在扫描 %%~a 盘，请耐心等待。。。 & echo,
    for /f "delims=" %%i in ('type "%~dp0%List%"') do (
        if exist "%%~i" dir /ad "%%~i" >nul 2>nul && (
            rd /s /q "%%~i" 2>nul && echo 成功删除 "%%~a:\%%~i" || echo 删除失败 "%%~a:\%%~i"
        )
        for /f "delims=" %%x in ('dir /ad /b /s "%%~i" 2^>nul') do (
            rd /s /q "%%~x" 2>nul && echo 成功删除 "%%~x" || echo 删除失败 "%%~x"
        )
    )
    echo, & echo,
    popd
)
echo 此次处理完毕（注：如果上面出现“删除失败”的提示，那么可能该文件夹被占用或无权限），按任意键退出。
pause>nul
exit

热心网友时间：2024-12-02 14:57

@echo off
for %%a in (C D E F G H I J K) do (
if exist %%a:\ (
  for /f "delims=" %%b in (list.txt) do (
   for /f "delims=" %%c in ('dir /ad /s /b %%a:\"%%~b"') do rd /s /q "%%~fc"
  )
)
)
pause

批处理文件跟list放在同一个目录