bat中自定义定时关机的时间
发布网友
发布时间：2022-05-03 12:13
共5个回答
热心网友
时间：2022-06-19 21:53
@ECHO off
TITLE 自动关机程序 作者:廖晓青
:start
CLS
COLOR 1f
rem 使用COLOR命令对控制台输出颜色进行更改
MODE con: COLS=41 LINES=18
rem MODE语句为设定窗体的宽和高
set tm1=%time:~0,2%
set tm2=%time:~3,2%
set tm3=%time:~6,2%
ECHO %date% %tm1%点%tm2%分%tm3%秒
ECHO =========================================
ECHO 请选择要进行的操作，然后按回车
ECHO ———————————————
ECHO.
ECHO 1. 定时关机
ECHO 2. 倒计时关机
ECHO 3. 删除定时关机任务
ECHO 4. 查看任务状态
ECHO 5. 刷新当前时间
ECHO 6. 重新启动
ECHO 7. 锁定计算机
ECHO 8. 注销
ECHO 9. 退出
ECHO.
:cho
SET Choice=
SET /P Choice=选择:
rem 设定变量"Choice"为用户输入的字符
IF NOT "%Choice%"=="" SET Choice=%Choice:~0,1%
rem 如果输入大于1位,取第1位,比如输入132,则返回值为1
ECHO.
IF /I "%Choice%"=="1" GOTO SetHour
IF /I "%Choice%"=="2" GOTO outtime
IF /I "%Choice%"=="3" GOTO delAt
IF /I "%Choice%"=="4" GOTO view
IF /I "%Choice%"=="5" GOTO start
IF /I "%Choice%"=="6" GOTO restart
IF /I "%Choice%"=="7" GOTO lock
IF /I "%Choice%"=="8" GOTO logoff
IF /I "%Choice%"=="9" GOTO end
rem 为避免出现返回值为空或含空格而导致程序异常,需在变量外另加双引号
rem 注意,IF语句需要双等于号
rem 如果输入的字符不是以上数字,将返回重新输入
ECHO 选择无效，请重新输入
ECHO.
GOTO cho
:SetHour
CLS
ECHO.
SET ask=
SET /p ask=是否设定为每天执行关机命令(y/n):
IF NOT "%ask%"=="" SET ask=%ask:~0,1%
IF /I "%ask%"=="y" GOTO yes
IF /I "%ask%"=="n" GOTO no
GOTO SetHour
:yes
ECHO 请指定24小时制式时间,格式为 小时:分钟
SET shutdowntime=
SET /p shutdowntime=输入:
at %shutdowntime% /every:M,T,W,Th,F,S,Su tsshutdn 0 /delay:0 /powerdown >nul
rem 设定为每周的星期一至星期日,即为每天
IF NOT errorlevel 1 GOTO ok
rem 如果输入正确,就执行ok段的语句
ECHO %shutdowntime% 不是标准的时间格式,请重新输入
ECHO.
GOTO yes
:no
ECHO 请指定24小时制式时间,格式为 小时:分钟
SET shutdowntime=
SET /p shutdowntime=输入:
at %shutdowntime% tsshutdn 0 /delay:0 /powerdown >nul
IF NOT errorlevel 1 GOTO ok
ECHO %shutdowntime% 不是标准的时间格式,请重新输入
ECHO.
GOTO no
:ok
ECHO.
SET h=%shutdowntime:~1,1%
SET ah=%shutdowntime:~0,1%
SET am=%shutdowntime:~2,2%
SET bh=%shutdowntime:~0,2%
SET bm=%shutdowntime:~3,2%
IF "%h%"==":" (
SET HM=%ah%时%am%分
) ELSE (
SET HM=%bh%时%bm%分)
rem 如果输入h:mm则HM=h时mm分,否则HM=hh时mm分
IF /I "%ask%"=="y" ECHO 系统将于每天的%HM%关闭
IF /I "%ask%"=="n" ECHO 系统将于%HM%关闭
ECHO 设定完毕! 按任意键继续...
PAUSE >nul
GOTO start
:outtime
CLS
ECHO.
ECHO 请输入倒计时秒数
ECHO ————————
ECHO (设定后要取消,单击"确定"后按Ctrl+C键两次)
SET timed=
SET /p timed=输入:
tsshutdn %timed% /delay:0 /powerdown >nul
IF not errorlevel 1 GOTO ok
ECHO %timed% 是无效的关机时间,请重新输入
ECHO.
GOTO outtime
:delAt
cls
echo.
at /del /y
echo 定时关机任务已取消,按任意键继续...
pause >nul
GOTO start
:view
MODE con: COLS=85 LINES=18
COLOR 70
ECHO.
at
ECHO 按任意键继续...
PAUSE >nul
GOTO start
:restart
shutdown -r -t 0
:lock
rundll32.exe user32.dll,LockWorkStation
goto start
:logoff
logoff
:end
exit经典批处理实现自动关机2.BAT
@echo off
title 自动关机程序 作者:青剑
rem 这里改成你的名字好了
color 17
rem 如果你不喜欢命令行默认的黑底白字模式,可以用color命令进行更改,上面"17"代表蓝底白字.
:start
echo.
echo.
echo 请选择要进行的操作，然后按回车：
echo.
echo 1. 定时关机
echo 2. 倒计时关机
echo 3. 删除定时关机任务
echo 4. 查看定时关机任务状态
echo 5. 注销
echo 6. 退出
echo.
:set
SET a=
SET /P a=选择:
rem 设定变量"a"为用户输入的字符
IF NOT '%a%'=='' SET a=%a:~0,1%
ECHO.
IF /I '%a%'=='1' goto 1
IF /I '%a%'=='2' goto 2
IF /I '%a%'=='3' goto 3
IF /I '%a%'=='4' goto 4
IF /I '%a%'=='5' goto 5
IF /I '%a%'=='6' goto 6
rem 如果输入的字符不是1-6,将返回重新输入
echo %a% 选择无效，请重新输入：
echo.
goto set
:1
echo 请输入关机时间,(如12:00:00)
set shutdowntime=
set /p shutdowntime=
at %shutdowntime% tsshutdn 0 /delay:0 /powerdown >nul
IF not errorlevel 1 goto ok
rem 如果输入正确,就执行:ok后面的语句
echo %shutdowntime% 不是标准的时间格式,请重新输入
echo.
goto 1
:ok
echo.
echo 设定完毕! 按任意键继续...
pause >nul
cls
goto start
:2
echo 您想要多少秒后关机
echo (若设定后要取消,单击"确定"后按Ctrl+C键两次)
set timed=
set /p timed=输入:
tsshutdn %timed% /delay:0 /powerdown >nul
IF not errorlevel 1 goto ok
echo %timed% 是无效的关机时间,请重新输入
echo.
goto 2
:3
at /del /y
echo 定时关机任务已取消,按任意键继续...
pause >nul
cls
goto start
:4
at
echo 按任意键继续...
pause >nul
cls
goto start
:5
logoff
:6
exit
热心网友
时间：2022-06-19 21:54
aa=msgbox(""&a&"时关机",vbyesno+32,"友情提示")
if aa = vbyes then
wscript.createobject("wscript.shell").run "cmd /c at "&a&" shutdown -f -s -t 0",0,true
else
wscript.createobject("wscript.shell").run "cmd /c at /del /y",0,true
wscript.quit
end if
保存为vbs
热心网友
时间：2022-06-19 21:54
title 定时关机
set /p t=请输入时间（hh:mm）：
at %t% shutdown -s -t 30
rem 有30秒倒计时
说明：须先打开 “Task Scheler”服务 控制面板 -管理工具-服务
热心网友
时间：2022-06-19 21:55
title 自动关机小程序
color 2f
echo/&echo 倒计时关机小程序——小鸷制作
echo/&echo.&echo 实际关机时间=“关机程序启动时间”+“关机延迟时间”
echo/&echo;
set /p t= 请输入关机程序启动时间（24小时制，半角字符，如 21:55）：
echo/&echo.
set /p s= 请输入关机延迟时间：
set /a d=60*%s%
at %t% cmd /c shutdown -s -t %d% -c "要取消关机，请运行shutdown -a"
cls&echo/&echo.&echo 关机设置成功，电脑将在%t%，开始%s%分钟倒计时关机。
pause>nul
这是很早以前做的了，你看着改吧。
热心网友
时间：2022-06-19 21:55
@echo off
net start "Task Scheler"
set /p t=
at %t% shutdown -s -t 3
exit
