求程序员帮写两个批处理程序

发布网友发布时间：2023-01-25 22:44

共2个回答

热心网友时间：2024-02-17 20:21

第一个要求的代码：

@echo off & title 批量转换 Word 类文档至文本文件 By 依梦琴瑶

::设置要处理的文件类型，以下为脚本支持的所有格式，如有不需要处理的格式，请自行删除。
set Ext=*.doc,*.xls,*.xlsb,*.ppt,*.rtf,*.odt,*.ods,*.odp,*.docx,*.xlsx,*.pptx,*.pages,*.numbers,*.keynote,*.fodp,*.fods,*.fodt,*.pdf,*.eml,*.html

::检查脚本所需运行库
set "YMQY=%AppData%\YiMengQinYao\doctotext"
set Path=%Path%;%YMQY%
if not exist "%YMQY%\doctotext.exe" goto SkipURL

::转换文档
color 0a & cls & cd /d %~dp0
for /f "delims=" %%a in ('dir /a-d/s/b %Ext%') do (
    echo 转换 "%%~nxa" 至 "%%~na_ss.txt" ...
    doctotext "%%~a" >nul 2>nul >"%%~dpna_ss.txt"
)
echo, & echo 所有文件转换完毕，请按任意键退出。
pause>nul & exit

::跳转运行库下载页面
:SkipURL
cls & Title 跳转运行库下载页面 By 依梦琴瑶
color 09 & mode 40,7
echo 由于您的电脑缺少相关运行库，
echo 请前往以下网址页面下载安装：
set "wA=ht"&set "wB=tps"&set "wC=://"&set "wD=pan"
set "wE="&set "wF="&set "wG=com"&set "wH=/s/"
set "PCode=1jHHiwOQ" & set "P_PSW="
set "PUrl=%wA%%wB%%wC%%wD%.%wE%%wF%.%wG%%wH%%PCode%"
echo, & echo     %PUrl% & echo, & echo 即将自动跳转。。。
ping 127.0.0.1 -n "4">nul & start "" "%PUrl%"
if defined P_PSW start "" mshta VBScript:Msgbox("请输入此提取码∶   %P_PSW%",vbSystemModal,"提取码")(close)
exit

效果图：

第二个要求的代码：

@echo off & title 替换文本文件至对应文档 By 依梦琴瑶
color 0a & cd /d %~dp0
setlocal enabledelayedexpansion

for /f "delims=" %%a in ('dir /a-d/s/b *_ss.txt') do (
    set "FileName=%%~dpna"
    call :ReplaceFile "!FileName:~,-3!" "%%~a"
)
echo, & echo 所有文件替换完毕，请按任意键退出。
pause>nul & exit

:ReplaceFile
for %%b in ("%~1.*") do (
    echo 替换 "%~nx2" 至 "%%~nxb" ...
    move /y "%~2" "%%~b" >nul
    goto :eof
)
goto :eof

效果图：

热心网友时间：2024-02-17 20:21

不玩bat好几年了。你自己搜搜相关案例自己弄吧。