如何用脚本实时启用、禁用网卡
发布网友
发布时间：2022-12-10 20:05
共3个回答
热心网友
时间：2024-12-15 02:21
======================================
Const ssfCONTROLS = 3
sConnectionName = "本地连接" '可改成需要控制的连接名称，如"无线网络连接"等
sEnableVerb = "启用(&A)"
sDisableVerb = "停用(&B)" 'XP系统中应为 "停用(&B)"
set shellApp = createobject("shell.application")
set oControlPanel = shellApp.Namespace(ssfCONTROLS)
set oNetConnections = nothing
for each folderitem in oControlPanel.items
if folderitem.name = "网络连接" then
set oNetConnections = folderitem.getfolder: exit for
end if
next
if oNetConnections is nothing then
msgbox "未找到网络连接文件夹"
wscript.quit
end if
set oLanConnection = nothing
for each folderitem in oNetConnections.items
if lcase(folderitem.name) = lcase(sConnectionName) then
set oLanConnection = folderitem: exit for
end if
next
if oLanConnection is nothing then
msgbox "未找到 '" & sConnectionName & "' item"
wscript.quit
end if
bEnabled = true
set oEnableVerb = nothing
set oDisableVerb = nothing
s = "Verbs: " & vbcrlf
for each verb in oLanConnection.verbs
s = s & vbcrlf & verb.name
if verb.name = sEnableVerb then
set oEnableVerb = verb
bEnabled = false
end if
if verb.name = sDisableVerb then
set oDisableVerb = verb
end if
next
'debugging displays left just in case...
'
'msgbox s ': wscript.quit
'msgbox "Enabled: " & bEnabled ': wscript.quit
'not sure why, but invokeverb always seemed to work
'for enable but not disable.
'
'saving a reference to the appropriate verb object
'and calling the DoIt method always seems to work.
'
if bEnabled then
' oLanConnection.invokeverb sDisableVerb
oDisableVerb.DoIt
else
' oLanConnection.invokeverb sEnableVerb
oEnableVerb.DoIt
end if
'adjust the sleep ration below as needed...
'
'if you let the oLanConnection go out of scope
'and be destroyed too soon, the action of the verb
'may not take...
'
wscript.sleep 400
==================
可以换个想法 简单的BAT脚本命令 就可以修改Ip 只要把IP改成 0.0.0.0 之类的 也就算变相的 关闭了网卡 呵呵
对不？
===========================
上面的脚本 用起来很简单
首先 建立个文本
把脚本复制到里面
其中
sEnableVerb = "启用(&A)"
sDisableVerb = "停用(&B)" 'XP系统中应为 "停用(&B)"
如果想停用的脚本 就去掉启用的命令 也就是
sEnableVerb = "启用(&A)"
这样下面的一样 这样就是启用的脚本
相反 sDisableVerb = "停用(&B)" 'XP系统中应为 "停用(&B)"
后面的一样 就是停用的脚本
保存好2个分别的脚本
然后改 后缀名为VBS 即可
或者
所有脚本不变 保存为一个文件脚本
那么 第一次应用是停止 第二次就是开启
====================
脚本没问题 能用
热心网友
时间：2024-12-15 02:21
在“选项”对话框中选择“调试”文件夹。
在“调试”文件夹中选择“实时”页。
在“启用这些代码类型的实时调试”框中，选中或清除相关的程序类型：“托管”、“本机”或“脚本”。
要在启用实时调试后禁用它，必须使用管理员特权运行。启用实时调试会设置一个注册表项，需要管理员特权才可以更改该项。
单击“确定”。
热心网友
时间：2024-12-15 02:22
netsh interface ip set address "连接名称"static 0.0.0.0 0.0.0.0 0.0.0.0 1
最后有一个1，一定要有呀
